Generating GORM Domain Classes

I am on a project that already had a legacy database in place with about 100 tables. I did not want to create my GORM domain classes manually for my Grails project. I am surprised that I did not find any existing code to handle this code generation so I created a Groovy script to handle this. I am sure this code could use some improvements such as handling more SQL types so I will just call it a 0.1 release because it does what I needed for now. Modify the sql varible so it has the right database connection information. Also, modify the tables hash so you can control which domain classes to generate based on a [tableName:className] structure.

   1  import groovy.sql.Sql
   2  import java.sql.Types
   3  
   4  sql = Sql.newInstance("jdbc:mysql://localhost:3306/pts_development",
   5                       "root",
   6                       "password",
   7                       "com.mysql.jdbc.Driver")
   8  
   9  // tables hash format => table : className
  10  tables = ['PTS_REG_DTL':'Detail','PTS_REG_MST':'Master']
  11  tables.each { table, className ->
  12      File file = new File("${className}.groovy")
  13      sb = new StringBuilder()
  14  
  15      fieldNames = []
  16      fieldTypes = []
  17  
  18      query = "select * from ${table}"
  19      sql.query(query.toString()){ rs ->
  20  
  21          sb << "class ${className} {\n"
  22  
  23          def meta = rs.metaData
  24          if(meta.columnCount <=0) return
  25  
  26          for(i in 1..meta.columnCount){
  27  
  28              fieldName = meta.getColumnName(i).toLowerCase().replaceAll(/_[\w]/,{ it[1].toUpperCase()})
  29              fieldNames << fieldName
  30              fieldType = ""
  31  
  32              switch(meta.getColumnType(i)) {
  33                  case Types.BIGINT:
  34                      fieldType = "Long"
  35                      break
  36                  case [Types.BINARY, Types.BIT, Types.BOOLEAN, Types.SMALLINT]:
  37                      fieldType = "Boolean"
  38                      break
  39                  case [Types.CHAR, Types.VARCHAR]:
  40                      fieldType = "String"
  41                      break
  42                  case [Types.DATE, Types.TIMESTAMP]:
  43                      fieldType = "Date"
  44                      break
  45                  case [Types.DECIMAL, Types.FLOAT]:
  46                      fieldType = "Decimal"
  47                      break
  48                  case [Types.INTEGER, Types.NUMERIC]:
  49                      fieldType = "Integer"
  50                      break
  51                  default:
  52                      fieldType = "Object"
  53              }
  54              fieldTypes << fieldType
  55              sb << "\t${fieldType} ${fieldName}\n"
  56          }
  57  
  58          // Print out the table mappings
  59          sb << "\tstatic mapping = {\n"
  60          sb << "\t\ttable '${table.toString()}'\n"
  61  
  62          for(j in 1..meta.columnCount) {
  63              sb << "\t\t${fieldNames[j-1]}  column:'${meta.getColumnName(j)}'\n"
  64          }
  65          sb << "\t}\n"
  66  
  67          // Print out the table constraints
  68          sb << "\tstatic constraints = {\n"
  69  
  70          for(k in 1..meta.columnCount) {
  71              sb << "\t\t${fieldNames[k-1]}("
  72              sb << "nullable:${meta.isNullable(k) ? 'true': 'false'}"
  73  
  74              if(fieldTypes[k] == 'String') {
  75                  sb << ", maxSize:${meta.getColumnDisplaySize(k)}"    
  76              }
  77              sb << ")\n"
  78          }
  79          sb << "\t }\n"
  80          sb << "}\n"
  81      }
  82      file.write(sb.toString())
  83  }

This code will generate a separate file for each domain class you specified in the tables hash in the current directory. Just make sure you have your database jar file in your classpath. Here is how you could run this code from the command line:

groovy -cp .:/Users/meagle/java/api/mysql-connector-java-5.0.4/mysql-connector-java-5.0.4-bin.jar GormGenerator.groovy